// skapa textflödets alla komponenter
var tContainer:Sprite = new Sprite();
addChild(tContainer);

var tController:ContainerController = new ContainerController(tContainer, 970, 645);

var tFormat:TextLayoutFormat = new TextLayoutFormat();
tFormat.fontFamily = "HelveticaNeue";
tFormat.fontSize = 48;
tFormat.color = 0x646464;
tFormat.direction = Direction.LTR;
tFormat.verticalAlign = VerticalAlign.MIDDLE;
tFormat.textAlign = TextAlign.CENTER;

if (embedFonts)
{	
 tFormat.cffHinting = CFFHinting.HORIZONTAL_STEM;
 tFormat.fontLookup = FontLookup.EMBEDDED_CFF;
}
else
{	
 tFormat.cffHinting = CFFHinting.NONE;
 tFormat.fontLookup = FontLookup.DEVICE;
}

var tTextFlow:TextFlow = new TextFlow();
tTextFlow.hostFormat = tFormat;

tTextFlow.flowComposer.addController(tController);

var tParagraph1:ParagraphElement = new ParagraphElement();
tParagraph1.paddingBottom = 40;
tTextFlow.addChild(tParagraph1);

var tSpan1:SpanElement = new SpanElement();
tSpan1.text = pTexts[0];

// spara FlowElement
var tSpanElement1:FlowElement = tParagraph1.addChild(tSpan1);

var tParagraph2:ParagraphElement = new ParagraphElement();
tParagraph2.paddingBottom = 15;
tParagraph2.paddingLeft = 10;
tTextFlow.addChild(tParagraph2);

var tIGE:InlineGraphicElement = new InlineGraphicElement();
tIGE.source = new Logo() as Bitmap;

// spara FlowElement
var tImageElement:FlowElement = tParagraph2.addChild(tIGE);

var tParagraph3:ParagraphElement = new ParagraphElement();
tTextFlow.addChild(tParagraph3);

var tSpan2:SpanElement = new SpanElement();
tSpan2.text = pTexts[1];

// spara FlowElement
var tSpanElement2:FlowElement = tParagraph3.addChild(tSpan2);

tTextFlow.flowComposer.updateAllControllers();

// hämta objekt
var tText1:DisplayObject = getProxy(tSpanElement1);
var tImage:DisplayObject = getProxy(tImageElement);
var tText2:DisplayObject = getProxy(tSpanElement2);

// sätt alpha = 0 på objekt som ska animeras
tText1.alpha = tImage.alpha = tText2.alpha = 0;

// animera objekten
var tText1Tween:GTween = new GTween( tText1, 1.2, { alpha : 1 }, { ease : Exponential.easeOut } );
var tImageTween:GTween = new GTween( tImage, 1.2, { alpha : 1 }, { ease : Exponential.easeOut, delay : 1 } );
var tText2Tween:GTween = new GTween( tText2, 1.2, { alpha : 1 }, { ease : Exponential.easeOut, delay : 2 } );

private function getProxy( recFlowElement : FlowElement ) : DisplayObject
{
 var tElement:FlowElement = recFlowElement;	
 if ( tElement == null )
 return null;	

 var tFlow:TextFlow = tElement.getTextFlow();
 if ( tFlow == null )	
 return null;	

 var tComposer:IFlowComposer = tFlow.flowComposer;	
 if ( tComposer == null )	
 return null;	

 var tPos:int = tElement.getAbsoluteStart();	
 var tLine:TextFlowLine = tComposer.findLineAtPosition( tPos );	

 return tLine.getTextLine( true );
}